efeae4c47a2faad2515469f2c34a5b0cb3565d96
1#!/usr/bin/perl
2#
3# Copyright 2002,2005 Greg Kroah-Hartman <greg@kroah.com>
4# Copyright 2005 Ryan Anderson <ryan@michonline.com>
5#
6# GPL v2 (See COPYING)
7#
8# Ported to support git "mbox" format files by Ryan Anderson <ryan@michonline.com>
9#
10# Sends a collection of emails to the given email addresses, disturbingly fast.
11#
12# Supports two formats:
13# 1. mbox format files (ignoring most headers and MIME formatting - this is designed for sending patches)
14# 2. The original format support by Greg's script:
15# first line of the message is who to CC,
16# and second line is the subject of the message.
17#
18use 5.008;
20use strict;
21use warnings;
22use Term::ReadLine;
23use Getopt::Long;
24use Text::ParseWords;
25use Data::Dumper;
26use Term::ANSIColor;
27use File::Temp qw/ tempdir tempfile /;
28use File::Spec::Functions qw(catfile);
29use Error qw(:try);
30use Git;
31Getopt::Long::Configure qw/ pass_through /;
33package FakeTerm;
35sub new {
36 my ($class, $reason) = @_;
37 return bless \$reason, shift;
38}
39sub readline {
40 my $self = shift;
41 die "Cannot use readline on FakeTerm: $$self";
42}
43package main;
44sub usage {
47 print <<EOT;
48git send-email [options] <file | directory | rev-list options >
49 Composing:
51 --from <str> * Email From:
52 --[no-]to <str> * Email To:
53 --[no-]cc <str> * Email Cc:
54 --[no-]bcc <str> * Email Bcc:
55 --subject <str> * Email "Subject:"
56 --in-reply-to <str> * Email "In-Reply-To:"
57 --annotate * Review each patch that will be sent in an editor.
58 --compose * Open an editor for introduction.
59 --compose-encoding <str> * Encoding to assume for introduction.
60 --8bit-encoding <str> * Encoding to assume 8bit mails if undeclared
61 Sending:
63 --envelope-sender <str> * Email envelope sender.
64 --smtp-server <str:int> * Outgoing SMTP server to use. The port
65 is optional. Default 'localhost'.
66 --smtp-server-option <str> * Outgoing SMTP server option to use.
67 --smtp-server-port <int> * Outgoing SMTP server port.
68 --smtp-user <str> * Username for SMTP-AUTH.
69 --smtp-pass <str> * Password for SMTP-AUTH; not necessary.
70 --smtp-encryption <str> * tls or ssl; anything else disables.
71 --smtp-ssl * Deprecated. Use '--smtp-encryption ssl'.
72 --smtp-domain <str> * The domain name sent to HELO/EHLO handshake
73 --smtp-debug <0|1> * Disable, enable Net::SMTP debug.
74 Automating:
76 --identity <str> * Use the sendemail.<id> options.
77 --to-cmd <str> * Email To: via `<str> \$patch_path`
78 --cc-cmd <str> * Email Cc: via `<str> \$patch_path`
79 --suppress-cc <str> * author, self, sob, cc, cccmd, body, bodycc, all.
80 --[no-]signed-off-by-cc * Send to Signed-off-by: addresses. Default on.
81 --[no-]suppress-from * Send to self. Default off.
82 --[no-]chain-reply-to * Chain In-Reply-To: fields. Default off.
83 --[no-]thread * Use In-Reply-To: field. Default on.
84 Administering:
86 --confirm <str> * Confirm recipients before sending;
87 auto, cc, compose, always, or never.
88 --quiet * Output one line of info per email.
89 --dry-run * Don't actually send the emails.
90 --[no-]validate * Perform patch sanity checks. Default on.
91 --[no-]format-patch * understand any non optional arguments as
92 `git format-patch` ones.
93 --force * Send even if safety checks would prevent it.
94EOT
96 exit(1);
97}
98# most mail servers generate the Date: header, but not all...
100sub format_2822_time {
101 my ($time) = @_;
102 my @localtm = localtime($time);
103 my @gmttm = gmtime($time);
104 my $localmin = $localtm[1] + $localtm[2] * 60;
105 my $gmtmin = $gmttm[1] + $gmttm[2] * 60;
106 if ($localtm[0] != $gmttm[0]) {
107 die "local zone differs from GMT by a non-minute interval\n";
108 }
109 if ((($gmttm[6] + 1) % 7) == $localtm[6]) {
110 $localmin += 1440;
111 } elsif ((($gmttm[6] - 1) % 7) == $localtm[6]) {
112 $localmin -= 1440;
113 } elsif ($gmttm[6] != $localtm[6]) {
114 die "local time offset greater than or equal to 24 hours\n";
115 }
116 my $offset = $localmin - $gmtmin;
117 my $offhour = $offset / 60;
118 my $offmin = abs($offset % 60);
119 if (abs($offhour) >= 24) {
120 die ("local time offset greater than or equal to 24 hours\n");
121 }
122 return sprintf("%s, %2d %s %d %02d:%02d:%02d %s%02d%02d",
124 qw(Sun Mon Tue Wed Thu Fri Sat)[$localtm[6]],
125 $localtm[3],
126 qw(Jan Feb Mar Apr May Jun
127 Jul Aug Sep Oct Nov Dec)[$localtm[4]],
128 $localtm[5]+1900,
129 $localtm[2],
130 $localtm[1],
131 $localtm[0],
132 ($offset >= 0) ? '+' : '-',
133 abs($offhour),
134 $offmin,
135 );
136}
137my $have_email_valid = eval { require Email::Valid; 1 };
139my $have_mail_address = eval { require Mail::Address; 1 };
140my $smtp;
141my $auth;
142# Variables we fill in automatically, or via prompting:
144my (@to,$no_to,@initial_to,@cc,$no_cc,@initial_cc,@bcclist,$no_bcc,@xh,
145 $initial_reply_to,$initial_subject,@files,
146 $author,$sender,$smtp_authpass,$annotate,$compose,$time);
147my $envelope_sender;
149# Example reply to:
151#$initial_reply_to = ''; #<20050203173208.GA23964@foobar.com>';
152my $repo = eval { Git->repository() };
154my @repo = $repo ? ($repo) : ();
155my $term = eval {
156 $ENV{"GIT_SEND_EMAIL_NOTTY"}
157 ? new Term::ReadLine 'git-send-email', \*STDIN, \*STDOUT
158 : new Term::ReadLine 'git-send-email';
159};
160if ($@) {
161 $term = new FakeTerm "$@: going non-interactive";
162}
163# Behavior modification variables
165my ($quiet, $dry_run) = (0, 0);
166my $format_patch;
167my $compose_filename;
168my $force = 0;
169# Handle interactive edition of files.
171my $multiedit;
172my $editor;
173sub do_edit {
175 if (!defined($editor)) {
176 $editor = Git::command_oneline('var', 'GIT_EDITOR');
177 }
178 if (defined($multiedit) && !$multiedit) {
179 map {
180 system('sh', '-c', $editor.' "$@"', $editor, $_);
181 if (($? & 127) || ($? >> 8)) {
182 die("the editor exited uncleanly, aborting everything");
183 }
184 } @_;
185 } else {
186 system('sh', '-c', $editor.' "$@"', $editor, @_);
187 if (($? & 127) || ($? >> 8)) {
188 die("the editor exited uncleanly, aborting everything");
189 }
190 }
191}
192# Variables with corresponding config settings
194my ($thread, $chain_reply_to, $suppress_from, $signed_off_by_cc);
195my ($to_cmd, $cc_cmd);
196my ($smtp_server, $smtp_server_port, @smtp_server_options);
197my ($smtp_authuser, $smtp_encryption);
198my ($identity, $aliasfiletype, @alias_files, $smtp_domain);
199my ($validate, $confirm);
200my (@suppress_cc);
201my ($auto_8bit_encoding);
202my ($compose_encoding);
203my ($debug_net_smtp) = 0; # Net::SMTP, see send_message()
205my $not_set_by_user = "true but not set by the user";
207my %config_bool_settings = (
209 "thread" => [\$thread, 1],
210 "chainreplyto" => [\$chain_reply_to, $not_set_by_user],
211 "suppressfrom" => [\$suppress_from, undef],
212 "signedoffbycc" => [\$signed_off_by_cc, undef],
213 "signedoffcc" => [\$signed_off_by_cc, undef], # Deprecated
214 "validate" => [\$validate, 1],
215 "multiedit" => [\$multiedit, undef]
216);
217my %config_settings = (
219 "smtpserver" => \$smtp_server,
220 "smtpserverport" => \$smtp_server_port,
221 "smtpserveroption" => \@smtp_server_options,
222 "smtpuser" => \$smtp_authuser,
223 "smtppass" => \$smtp_authpass,
224 "smtpdomain" => \$smtp_domain,
225 "to" => \@initial_to,
226 "tocmd" => \$to_cmd,
227 "cc" => \@initial_cc,
228 "cccmd" => \$cc_cmd,
229 "aliasfiletype" => \$aliasfiletype,
230 "bcc" => \@bcclist,
231 "suppresscc" => \@suppress_cc,
232 "envelopesender" => \$envelope_sender,
233 "confirm" => \$confirm,
234 "from" => \$sender,
235 "assume8bitencoding" => \$auto_8bit_encoding,
236 "composeencoding" => \$compose_encoding,
237);
238my %config_path_settings = (
240 "aliasesfile" => \@alias_files,
241);
242# Help users prepare for 1.7.0
244sub chain_reply_to {
245 if (defined $chain_reply_to &&
246 $chain_reply_to eq $not_set_by_user) {
247 print STDERR
248 "In git 1.7.0, the default has changed to --no-chain-reply-to\n" .
249 "Set sendemail.chainreplyto configuration variable to true if\n" .
250 "you want to keep --chain-reply-to as your default.\n";
251 $chain_reply_to = 0;
252 }
253 return $chain_reply_to;
254}
255# Handle Uncouth Termination
257sub signal_handler {
258 # Make text normal
260 print color("reset"), "\n";
261 # SMTP password masked
263 system "stty echo";
264 # tmp files from --compose
266 if (defined $compose_filename) {
267 if (-e $compose_filename) {
268 print "'$compose_filename' contains an intermediate version of the email you were composing.\n";
269 }
270 if (-e ($compose_filename . ".final")) {
271 print "'$compose_filename.final' contains the composed email.\n"
272 }
273 }
274 exit;
276};
277$SIG{TERM} = \&signal_handler;
279$SIG{INT} = \&signal_handler;
280# Begin by accumulating all the variables (defined above), that we will end up
282# needing, first, from the command line:
283my $help;
285my $rc = GetOptions("h" => \$help,
286 "sender|from=s" => \$sender,
287 "in-reply-to=s" => \$initial_reply_to,
288 "subject=s" => \$initial_subject,
289 "to=s" => \@initial_to,
290 "to-cmd=s" => \$to_cmd,
291 "no-to" => \$no_to,
292 "cc=s" => \@initial_cc,
293 "no-cc" => \$no_cc,
294 "bcc=s" => \@bcclist,
295 "no-bcc" => \$no_bcc,
296 "chain-reply-to!" => \$chain_reply_to,
297 "smtp-server=s" => \$smtp_server,
298 "smtp-server-option=s" => \@smtp_server_options,
299 "smtp-server-port=s" => \$smtp_server_port,
300 "smtp-user=s" => \$smtp_authuser,
301 "smtp-pass:s" => \$smtp_authpass,
302 "smtp-ssl" => sub { $smtp_encryption = 'ssl' },
303 "smtp-encryption=s" => \$smtp_encryption,
304 "smtp-debug:i" => \$debug_net_smtp,
305 "smtp-domain:s" => \$smtp_domain,
306 "identity=s" => \$identity,
307 "annotate" => \$annotate,
308 "compose" => \$compose,
309 "quiet" => \$quiet,
310 "cc-cmd=s" => \$cc_cmd,
311 "suppress-from!" => \$suppress_from,
312 "suppress-cc=s" => \@suppress_cc,
313 "signed-off-cc|signed-off-by-cc!" => \$signed_off_by_cc,
314 "confirm=s" => \$confirm,
315 "dry-run" => \$dry_run,
316 "envelope-sender=s" => \$envelope_sender,
317 "thread!" => \$thread,
318 "validate!" => \$validate,
319 "format-patch!" => \$format_patch,
320 "8bit-encoding=s" => \$auto_8bit_encoding,
321 "compose-encoding=s" => \$compose_encoding,
322 "force" => \$force,
323 );
324usage() if $help;
326unless ($rc) {
327 usage();
328}
329die "Cannot run git format-patch from outside a repository\n"
331 if $format_patch and not $repo;
332# Now, let's fill any that aren't set in with defaults:
334sub read_config {
336 my ($prefix) = @_;
337 foreach my $setting (keys %config_bool_settings) {
339 my $target = $config_bool_settings{$setting}->[0];
340 $$target = Git::config_bool(@repo, "$prefix.$setting") unless (defined $$target);
341 }
342 foreach my $setting (keys %config_path_settings) {
344 my $target = $config_path_settings{$setting};
345 if (ref($target) eq "ARRAY") {
346 unless (@$target) {
347 my @values = Git::config_path(@repo, "$prefix.$setting");
348 @$target = @values if (@values && defined $values[0]);
349 }
350 }
351 else {
352 $$target = Git::config_path(@repo, "$prefix.$setting") unless (defined $$target);
353 }
354 }
355 foreach my $setting (keys %config_settings) {
357 my $target = $config_settings{$setting};
358 next if $setting eq "to" and defined $no_to;
359 next if $setting eq "cc" and defined $no_cc;
360 next if $setting eq "bcc" and defined $no_bcc;
361 if (ref($target) eq "ARRAY") {
362 unless (@$target) {
363 my @values = Git::config(@repo, "$prefix.$setting");
364 @$target = @values if (@values && defined $values[0]);
365 }
366 }
367 else {
368 $$target = Git::config(@repo, "$prefix.$setting") unless (defined $$target);
369 }
370 }
371 if (!defined $smtp_encryption) {
373 my $enc = Git::config(@repo, "$prefix.smtpencryption");
374 if (defined $enc) {
375 $smtp_encryption = $enc;
376 } elsif (Git::config_bool(@repo, "$prefix.smtpssl")) {
377 $smtp_encryption = 'ssl';
378 }
379 }
380}
381# read configuration from [sendemail "$identity"], fall back on [sendemail]
383$identity = Git::config(@repo, "sendemail.identity") unless (defined $identity);
384read_config("sendemail.$identity") if (defined $identity);
385read_config("sendemail");
386# fall back on builtin bool defaults
388foreach my $setting (values %config_bool_settings) {
389 ${$setting->[0]} = $setting->[1] unless (defined (${$setting->[0]}));
390}
391# 'default' encryption is none -- this only prevents a warning
393$smtp_encryption = '' unless (defined $smtp_encryption);
394# Set CC suppressions
396my(%suppress_cc);
397if (@suppress_cc) {
398 foreach my $entry (@suppress_cc) {
399 die "Unknown --suppress-cc field: '$entry'\n"
400 unless $entry =~ /^(?:all|cccmd|cc|author|self|sob|body|bodycc)$/;
401 $suppress_cc{$entry} = 1;
402 }
403}
404if ($suppress_cc{'all'}) {
406 foreach my $entry (qw (cccmd cc author self sob body bodycc)) {
407 $suppress_cc{$entry} = 1;
408 }
409 delete $suppress_cc{'all'};
410}
411# If explicit old-style ones are specified, they trump --suppress-cc.
413$suppress_cc{'self'} = $suppress_from if defined $suppress_from;
414$suppress_cc{'sob'} = !$signed_off_by_cc if defined $signed_off_by_cc;
415if ($suppress_cc{'body'}) {
417 foreach my $entry (qw (sob bodycc)) {
418 $suppress_cc{$entry} = 1;
419 }
420 delete $suppress_cc{'body'};
421}
422# Set confirm's default value
424my $confirm_unconfigured = !defined $confirm;
425if ($confirm_unconfigured) {
426 $confirm = scalar %suppress_cc ? 'compose' : 'auto';
427};
428die "Unknown --confirm setting: '$confirm'\n"
429 unless $confirm =~ /^(?:auto|cc|compose|always|never)/;
430# Debugging, print out the suppressions.
432if (0) {
433 print "suppressions:\n";
434 foreach my $entry (keys %suppress_cc) {
435 printf " %-5s -> $suppress_cc{$entry}\n", $entry;
436 }
437}
438my ($repoauthor, $repocommitter);
440($repoauthor) = Git::ident_person(@repo, 'author');
441($repocommitter) = Git::ident_person(@repo, 'committer');
442# Verify the user input
444foreach my $entry (@initial_to) {
446 die "Comma in --to entry: $entry'\n" unless $entry !~ m/,/;
447}
448foreach my $entry (@initial_cc) {
450 die "Comma in --cc entry: $entry'\n" unless $entry !~ m/,/;
451}
452foreach my $entry (@bcclist) {
454 die "Comma in --bcclist entry: $entry'\n" unless $entry !~ m/,/;
455}
456sub parse_address_line {
458 if ($have_mail_address) {
459 return map { $_->format } Mail::Address->parse($_[0]);
460 } else {
461 return split_addrs($_[0]);
462 }
463}
464sub split_addrs {
466 return quotewords('\s*,\s*', 1, @_);
467}
468my %aliases;
470my %parse_alias = (
471 # multiline formats can be supported in the future
472 mutt => sub { my $fh = shift; while (<$fh>) {
473 if (/^\s*alias\s+(?:-group\s+\S+\s+)*(\S+)\s+(.*)$/) {
474 my ($alias, $addr) = ($1, $2);
475 $addr =~ s/#.*$//; # mutt allows # comments
476 # commas delimit multiple addresses
477 $aliases{$alias} = [ split_addrs($addr) ];
478 }}},
479 mailrc => sub { my $fh = shift; while (<$fh>) {
480 if (/^alias\s+(\S+)\s+(.*)$/) {
481 # spaces delimit multiple addresses
482 $aliases{$1} = [ quotewords('\s+', 0, $2) ];
483 }}},
484 pine => sub { my $fh = shift; my $f='\t[^\t]*';
485 for (my $x = ''; defined($x); $x = $_) {
486 chomp $x;
487 $x .= $1 while(defined($_ = <$fh>) && /^ +(.*)$/);
488 $x =~ /^(\S+)$f\t\(?([^\t]+?)\)?(:?$f){0,2}$/ or next;
489 $aliases{$1} = [ split_addrs($2) ];
490 }},
491 elm => sub { my $fh = shift;
492 while (<$fh>) {
493 if (/^(\S+)\s+=\s+[^=]+=\s(\S+)/) {
494 my ($alias, $addr) = ($1, $2);
495 $aliases{$alias} = [ split_addrs($addr) ];
496 }
497 } },
498 gnus => sub { my $fh = shift; while (<$fh>) {
500 if (/\(define-mail-alias\s+"(\S+?)"\s+"(\S+?)"\)/) {
501 $aliases{$1} = [ $2 ];
502 }}}
503);
504if (@alias_files and $aliasfiletype and defined $parse_alias{$aliasfiletype}) {
506 foreach my $file (@alias_files) {
507 open my $fh, '<', $file or die "opening $file: $!\n";
508 $parse_alias{$aliasfiletype}->($fh);
509 close $fh;
510 }
511}
512($sender) = expand_aliases($sender) if defined $sender;
514# returns 1 if the conflict must be solved using it as a format-patch argument
516sub check_file_rev_conflict($) {
517 return unless $repo;
518 my $f = shift;
519 try {
520 $repo->command('rev-parse', '--verify', '--quiet', $f);
521 if (defined($format_patch)) {
522 return $format_patch;
523 }
524 die(<<EOF);
525File '$f' exists but it could also be the range of commits
526to produce patches for. Please disambiguate by...
527 * Saying "./$f" if you mean a file; or
529 * Giving --format-patch option if you mean a range.
530EOF
531 } catch Git::Error::Command with {
532 return 0;
533 }
534}
535# Now that all the defaults are set, process the rest of the command line
537# arguments and collect up the files that need to be processed.
538my @rev_list_opts;
539while (defined(my $f = shift @ARGV)) {
540 if ($f eq "--") {
541 push @rev_list_opts, "--", @ARGV;
542 @ARGV = ();
543 } elsif (-d $f and !check_file_rev_conflict($f)) {
544 opendir my $dh, $f
545 or die "Failed to opendir $f: $!";
546 push @files, grep { -f $_ } map { catfile($f, $_) }
548 sort readdir $dh;
549 closedir $dh;
550 } elsif ((-f $f or -p $f) and !check_file_rev_conflict($f)) {
551 push @files, $f;
552 } else {
553 push @rev_list_opts, $f;
554 }
555}
556if (@rev_list_opts) {
558 die "Cannot run git format-patch from outside a repository\n"
559 unless $repo;
560 push @files, $repo->command('format-patch', '-o', tempdir(CLEANUP => 1), @rev_list_opts);
561}
562if ($validate) {
564 foreach my $f (@files) {
565 unless (-p $f) {
566 my $error = validate_patch($f);
567 $error and die "fatal: $f: $error\nwarning: no patches were sent\n";
568 }
569 }
570}
571if (@files) {
573 unless ($quiet) {
574 print $_,"\n" for (@files);
575 }
576} else {
577 print STDERR "\nNo patch files specified!\n\n";
578 usage();
579}
580sub get_patch_subject {
582 my $fn = shift;
583 open (my $fh, '<', $fn);
584 while (my $line = <$fh>) {
585 next unless ($line =~ /^Subject: (.*)$/);
586 close $fh;
587 return "GIT: $1\n";
588 }
589 close $fh;
590 die "No subject line in $fn ?";
591}
592if ($compose) {
594 # Note that this does not need to be secure, but we will make a small
595 # effort to have it be unique
596 $compose_filename = ($repo ?
597 tempfile(".gitsendemail.msg.XXXXXX", DIR => $repo->repo_path()) :
598 tempfile(".gitsendemail.msg.XXXXXX", DIR => "."))[1];
599 open my $c, ">", $compose_filename
600 or die "Failed to open for writing $compose_filename: $!";
601 my $tpl_sender = $sender || $repoauthor || $repocommitter || '';
604 my $tpl_subject = $initial_subject || '';
605 my $tpl_reply_to = $initial_reply_to || '';
606 print $c <<EOT;
608From $tpl_sender # This line is ignored.
609GIT: Lines beginning in "GIT:" will be removed.
610GIT: Consider including an overall diffstat or table of contents
611GIT: for the patch you are writing.
612GIT:
613GIT: Clear the body content if you don't wish to send a summary.
614From: $tpl_sender
615Subject: $tpl_subject
616In-Reply-To: $tpl_reply_to
617EOT
619 for my $f (@files) {
620 print $c get_patch_subject($f);
621 }
622 close $c;
623 if ($annotate) {
625 do_edit($compose_filename, @files);
626 } else {
627 do_edit($compose_filename);
628 }
629 open my $c2, ">", $compose_filename . ".final"
631 or die "Failed to open $compose_filename.final : " . $!;
632 open $c, "<", $compose_filename
634 or die "Failed to open $compose_filename : " . $!;
635 my $need_8bit_cte = file_has_nonascii($compose_filename);
637 my $in_body = 0;
638 my $summary_empty = 1;
639 if (!defined $compose_encoding) {
640 $compose_encoding = "UTF-8";
641 }
642 while(<$c>) {
643 next if m/^GIT:/;
644 if ($in_body) {
645 $summary_empty = 0 unless (/^\n$/);
646 } elsif (/^\n$/) {
647 $in_body = 1;
648 if ($need_8bit_cte) {
649 print $c2 "MIME-Version: 1.0\n",
650 "Content-Type: text/plain; ",
651 "charset=$compose_encoding\n",
652 "Content-Transfer-Encoding: 8bit\n";
653 }
654 } elsif (/^MIME-Version:/i) {
655 $need_8bit_cte = 0;
656 } elsif (/^Subject:\s*(.+)\s*$/i) {
657 $initial_subject = $1;
658 my $subject = $initial_subject;
659 $_ = "Subject: " .
660 ($subject =~ /[^[:ascii:]]/ ?
661 quote_rfc2047($subject, $compose_encoding) :
662 $subject) .
663 "\n";
664 } elsif (/^In-Reply-To:\s*(.+)\s*$/i) {
665 $initial_reply_to = $1;
666 next;
667 } elsif (/^From:\s*(.+)\s*$/i) {
668 $sender = $1;
669 next;
670 } elsif (/^(?:To|Cc|Bcc):/i) {
671 print "To/Cc/Bcc fields are not interpreted yet, they have been ignored\n";
672 next;
673 }
674 print $c2 $_;
675 }
676 close $c;
677 close $c2;
678 if ($summary_empty) {
680 print "Summary email is empty, skipping it\n";
681 $compose = -1;
682 }
683} elsif ($annotate) {
684 do_edit(@files);
685}
686sub ask {
688 my ($prompt, %arg) = @_;
689 my $valid_re = $arg{valid_re};
690 my $default = $arg{default};
691 my $confirm_only = $arg{confirm_only};
692 my $resp;
693 my $i = 0;
694 return defined $default ? $default : undef
695 unless defined $term->IN and defined fileno($term->IN) and
696 defined $term->OUT and defined fileno($term->OUT);
697 while ($i++ < 10) {
698 $resp = $term->readline($prompt);
699 if (!defined $resp) { # EOF
700 print "\n";
701 return defined $default ? $default : undef;
702 }
703 if ($resp eq '' and defined $default) {
704 return $default;
705 }
706 if (!defined $valid_re or $resp =~ /$valid_re/) {
707 return $resp;
708 }
709 if ($confirm_only) {
710 my $yesno = $term->readline("Are you sure you want to use <$resp> [y/N]? ");
711 if (defined $yesno && $yesno =~ /y/i) {
712 return $resp;
713 }
714 }
715 }
716 return undef;
717}
718my %broken_encoding;
720sub file_declares_8bit_cte {
722 my $fn = shift;
723 open (my $fh, '<', $fn);
724 while (my $line = <$fh>) {
725 last if ($line =~ /^$/);
726 return 1 if ($line =~ /^Content-Transfer-Encoding: .*8bit.*$/);
727 }
728 close $fh;
729 return 0;
730}
731foreach my $f (@files) {
733 next unless (body_or_subject_has_nonascii($f)
734 && !file_declares_8bit_cte($f));
735 $broken_encoding{$f} = 1;
736}
737if (!defined $auto_8bit_encoding && scalar %broken_encoding) {
739 print "The following files are 8bit, but do not declare " .
740 "a Content-Transfer-Encoding.\n";
741 foreach my $f (sort keys %broken_encoding) {
742 print " $f\n";
743 }
744 $auto_8bit_encoding = ask("Which 8bit encoding should I declare [UTF-8]? ",
745 default => "UTF-8");
746}
747if (!$force) {
749 for my $f (@files) {
750 if (get_patch_subject($f) =~ /\Q*** SUBJECT HERE ***\E/) {
751 die "Refusing to send because the patch\n\t$f\n"
752 . "has the template subject '*** SUBJECT HERE ***'. "
753 . "Pass --force if you really want to send.\n";
754 }
755 }
756}
757my $prompting = 0;
759if (!defined $sender) {
760 $sender = $repoauthor || $repocommitter || '';
761 $sender = ask("Who should the emails appear to be from? [$sender] ",
762 default => $sender,
763 valid_re => qr/\@.*\./, confirm_only => 1);
764 print "Emails will be sent from: ", $sender, "\n";
765 $prompting++;
766}
767if (!@initial_to && !defined $to_cmd) {
769 my $to = ask("Who should the emails be sent to (if any)? ",
770 default => "",
771 valid_re => qr/\@.*\./, confirm_only => 1);
772 push @initial_to, parse_address_line($to) if defined $to; # sanitized/validated later
773 $prompting++;
774}
775sub expand_aliases {
777 return map { expand_one_alias($_) } @_;
778}
779my %EXPANDED_ALIASES;
781sub expand_one_alias {
782 my $alias = shift;
783 if ($EXPANDED_ALIASES{$alias}) {
784 die "fatal: alias '$alias' expands to itself\n";
785 }
786 local $EXPANDED_ALIASES{$alias} = 1;
787 return $aliases{$alias} ? expand_aliases(@{$aliases{$alias}}) : $alias;
788}
789@initial_to = expand_aliases(@initial_to);
791@initial_to = (map { sanitize_address($_) } @initial_to);
792@initial_cc = expand_aliases(@initial_cc);
793@bcclist = expand_aliases(@bcclist);
794if ($thread && !defined $initial_reply_to && $prompting) {
796 $initial_reply_to = ask(
797 "Message-ID to be used as In-Reply-To for the first email (if any)? ",
798 default => "",
799 valid_re => qr/\@.*\./, confirm_only => 1);
800}
801if (defined $initial_reply_to) {
802 $initial_reply_to =~ s/^\s*<?//;
803 $initial_reply_to =~ s/>?\s*$//;
804 $initial_reply_to = "<$initial_reply_to>" if $initial_reply_to ne '';
805}
806if (!defined $smtp_server) {
808 foreach (qw( /usr/sbin/sendmail /usr/lib/sendmail )) {
809 if (-x $_) {
810 $smtp_server = $_;
811 last;
812 }
813 }
814 $smtp_server ||= 'localhost'; # could be 127.0.0.1, too... *shrug*
815}
816if ($compose && $compose > 0) {
818 @files = ($compose_filename . ".final", @files);
819}
820# Variables we set as part of the loop over files
822our ($message_id, %mail, $subject, $reply_to, $references, $message,
823 $needs_confirm, $message_num, $ask_default);
824sub extract_valid_address {
826 my $address = shift;
827 my $local_part_regexp = qr/[^<>"\s@]+/;
828 my $domain_regexp = qr/[^.<>"\s@]+(?:\.[^.<>"\s@]+)+/;
829 # check for a local address:
831 return $address if ($address =~ /^($local_part_regexp)$/);
832 $address =~ s/^\s*<(.*)>\s*$/$1/;
834 if ($have_email_valid) {
835 return scalar Email::Valid->address($address);
836 } else {
837 # less robust/correct than the monster regexp in Email::Valid,
838 # but still does a 99% job, and one less dependency
839 $address =~ /($local_part_regexp\@$domain_regexp)/;
840 return $1;
841 }
842}
843# Usually don't need to change anything below here.
845# we make a "fake" message id by taking the current number
847# of seconds since the beginning of Unix time and tacking on
848# a random number to the end, in case we are called quicker than
849# 1 second since the last time we were called.
850# We'll setup a template for the message id, using the "from" address:
852my ($message_id_stamp, $message_id_serial);
854sub make_message_id {
855 my $uniq;
856 if (!defined $message_id_stamp) {
857 $message_id_stamp = sprintf("%s-%s", time, $$);
858 $message_id_serial = 0;
859 }
860 $message_id_serial++;
861 $uniq = "$message_id_stamp-$message_id_serial";
862 my $du_part;
864 for ($sender, $repocommitter, $repoauthor) {
865 $du_part = extract_valid_address(sanitize_address($_));
866 last if (defined $du_part and $du_part ne '');
867 }
868 if (not defined $du_part or $du_part eq '') {
869 require Sys::Hostname;
870 $du_part = 'user@' . Sys::Hostname::hostname();
871 }
872 my $message_id_template = "<%s-git-send-email-%s>";
873 $message_id = sprintf($message_id_template, $uniq, $du_part);
874 #print "new message id = $message_id\n"; # Was useful for debugging
875}
876$time = time - scalar $#files;
880sub unquote_rfc2047 {
882 local ($_) = @_;
883 my $encoding;
884 s{=\?([^?]+)\?q\?(.*?)\?=}{
885 $encoding = $1;
886 my $e = $2;
887 $e =~ s/_/ /g;
888 $e =~ s/=([0-9A-F]{2})/chr(hex($1))/eg;
889 $e;
890 }eg;
891 return wantarray ? ($_, $encoding) : $_;
892}
893sub quote_rfc2047 {
895 local $_ = shift;
896 my $encoding = shift || 'UTF-8';
897 s/([^-a-zA-Z0-9!*+\/])/sprintf("=%02X", ord($1))/eg;
898 s/(.*)/=\?$encoding\?q\?$1\?=/;
899 return $_;
900}
901sub is_rfc2047_quoted {
903 my $s = shift;
904 my $token = qr/[^][()<>@,;:"\/?.= \000-\037\177-\377]+/;
905 my $encoded_text = qr/[!->@-~]+/;
906 length($s) <= 75 &&
907 $s =~ m/^(?:"[[:ascii:]]*"|=\?$token\?$token\?$encoded_text\?=)$/o;
908}
909# use the simplest quoting being able to handle the recipient
911sub sanitize_address {
912 my ($recipient) = @_;
913 my ($recipient_name, $recipient_addr) = ($recipient =~ /^(.*?)\s*(<.*)/);
914 if (not $recipient_name) {
916 return $recipient;
917 }
918 # if recipient_name is already quoted, do nothing
920 if (is_rfc2047_quoted($recipient_name)) {
921 return $recipient;
922 }
923 # rfc2047 is needed if a non-ascii char is included
925 if ($recipient_name =~ /[^[:ascii:]]/) {
926 $recipient_name =~ s/^"(.*)"$/$1/;
927 $recipient_name = quote_rfc2047($recipient_name);
928 }
929 # double quotes are needed if specials or CTLs are included
931 elsif ($recipient_name =~ /[][()<>@,;:\\".\000-\037\177]/) {
932 $recipient_name =~ s/(["\\\r])/\\$1/g;
933 $recipient_name = qq["$recipient_name"];
934 }
935 return "$recipient_name $recipient_addr";
937}
939# Returns the local Fully Qualified Domain Name (FQDN) if available.
941#
942# Tightly configured MTAa require that a caller sends a real DNS
943# domain name that corresponds the IP address in the HELO/EHLO
944# handshake. This is used to verify the connection and prevent
945# spammers from trying to hide their identity. If the DNS and IP don't
946# match, the receiveing MTA may deny the connection.
947#
948# Here is a deny example of Net::SMTP with the default "localhost.localdomain"
949#
950# Net::SMTP=GLOB(0x267ec28)>>> EHLO localhost.localdomain
951# Net::SMTP=GLOB(0x267ec28)<<< 550 EHLO argument does not match calling host
952#
953# This maildomain*() code is based on ideas in Perl library Test::Reporter
954# /usr/share/perl5/Test/Reporter/Mail/Util.pm ==> sub _maildomain ()
955sub valid_fqdn {
957 my $domain = shift;
958 return defined $domain && !($^O eq 'darwin' && $domain =~ /\.local$/) && $domain =~ /\./;
959}
960sub maildomain_net {
962 my $maildomain;
963 if (eval { require Net::Domain; 1 }) {
965 my $domain = Net::Domain::domainname();
966 $maildomain = $domain if valid_fqdn($domain);
967 }
968 return $maildomain;
970}
971sub maildomain_mta {
973 my $maildomain;
974 if (eval { require Net::SMTP; 1 }) {
976 for my $host (qw(mailhost localhost)) {
977 my $smtp = Net::SMTP->new($host);
978 if (defined $smtp) {
979 my $domain = $smtp->domain;
980 $smtp->quit;
981 $maildomain = $domain if valid_fqdn($domain);
983 last if $maildomain;
985 }
986 }
987 }
988 return $maildomain;
990}
991sub maildomain {
993 return maildomain_net() || maildomain_mta() || 'localhost.localdomain';
994}
995# Returns 1 if the message was sent, and 0 otherwise.
997# In actuality, the whole program dies when there
998# is an error sending a message.
999sub send_message {
1001 my @recipients = unique_email_list(@to);
1002 @cc = (grep { my $cc = extract_valid_address($_);
1003 not grep { $cc eq $_ || $_ =~ /<\Q${cc}\E>$/ } @recipients
1004 }
1005 map { sanitize_address($_) }
1006 @cc);
1007 my $to = join (",\n\t", @recipients);
1008 @recipients = unique_email_list(@recipients,@cc,@bcclist);
1009 @recipients = (map { extract_valid_address($_) } @recipients);
1010 my $date = format_2822_time($time++);
1011 my $gitversion = '@@GIT_VERSION@@';
1012 if ($gitversion =~ m/..GIT_VERSION../) {
1013 $gitversion = Git::version();
1014 }
1015 my $cc = join(",\n\t", unique_email_list(@cc));
1017 my $ccline = "";
1018 if ($cc ne '') {
1019 $ccline = "\nCc: $cc";
1020 }
1021 my $sanitized_sender = sanitize_address($sender);
1022 make_message_id() unless defined($message_id);
1023 my $header = "From: $sanitized_sender
1025To: $to${ccline}
1026Subject: $subject
1027Date: $date
1028Message-Id: $message_id
1029X-Mailer: git-send-email $gitversion
1030";
1031 if ($reply_to) {
1032 $header .= "In-Reply-To: $reply_to\n";
1034 $header .= "References: $references\n";
1035 }
1036 if (@xh) {
1037 $header .= join("\n", @xh) . "\n";
1038 }
1039 my @sendmail_parameters = ('-i', @recipients);
1041 my $raw_from = $sanitized_sender;
1042 if (defined $envelope_sender && $envelope_sender ne "auto") {
1043 $raw_from = $envelope_sender;
1044 }
1045 $raw_from = extract_valid_address($raw_from);
1046 unshift (@sendmail_parameters,
1047 '-f', $raw_from) if(defined $envelope_sender);
1048 if ($needs_confirm && !$dry_run) {
1050 print "\n$header\n";
1051 if ($needs_confirm eq "inform") {
1052 $confirm_unconfigured = 0; # squelch this message for the rest of this run
1053 $ask_default = "y"; # assume yes on EOF since user hasn't explicitly asked for confirmation
1054 print " The Cc list above has been expanded by additional\n";
1055 print " addresses found in the patch commit message. By default\n";
1056 print " send-email prompts before sending whenever this occurs.\n";
1057 print " This behavior is controlled by the sendemail.confirm\n";
1058 print " configuration setting.\n";
1059 print "\n";
1060 print " For additional information, run 'git send-email --help'.\n";
1061 print " To retain the current behavior, but squelch this message,\n";
1062 print " run 'git config --global sendemail.confirm auto'.\n\n";
1063 }
1064 $_ = ask("Send this email? ([y]es|[n]o|[q]uit|[a]ll): ",
1065 valid_re => qr/^(?:yes|y|no|n|quit|q|all|a)/i,
1066 default => $ask_default);
1067 die "Send this email reply required" unless defined $_;
1068 if (/^n/i) {
1069 return 0;
1070 } elsif (/^q/i) {
1071 cleanup_compose_files();
1072 exit(0);
1073 } elsif (/^a/i) {
1074 $confirm = 'never';
1075 }
1076 }
1077 unshift (@sendmail_parameters, @smtp_server_options);
1079 if ($dry_run) {
1081 # We don't want to send the email.
1082 } elsif ($smtp_server =~ m#^/#) {
1083 my $pid = open my $sm, '|-';
1084 defined $pid or die $!;
1085 if (!$pid) {
1086 exec($smtp_server, @sendmail_parameters) or die $!;
1087 }
1088 print $sm "$header\n$message";
1089 close $sm or die $!;
1090 } else {
1091 if (!defined $smtp_server) {
1093 die "The required SMTP server is not properly defined."
1094 }
1095 if ($smtp_encryption eq 'ssl') {
1097 $smtp_server_port ||= 465; # ssmtp
1098 require Net::SMTP::SSL;
1099 $smtp_domain ||= maildomain();
1100 $smtp ||= Net::SMTP::SSL->new($smtp_server,
1101 Hello => $smtp_domain,
1102 Port => $smtp_server_port);
1103 }
1104 else {
1105 require Net::SMTP;
1106 $smtp_domain ||= maildomain();
1107 $smtp ||= Net::SMTP->new((defined $smtp_server_port)
1108 ? "$smtp_server:$smtp_server_port"
1109 : $smtp_server,
1110 Hello => $smtp_domain,
1111 Debug => $debug_net_smtp);
1112 if ($smtp_encryption eq 'tls' && $smtp) {
1113 require Net::SMTP::SSL;
1114 $smtp->command('STARTTLS');
1115 $smtp->response();
1116 if ($smtp->code == 220) {
1117 $smtp = Net::SMTP::SSL->start_SSL($smtp)
1118 or die "STARTTLS failed! ".$smtp->message;
1119 $smtp_encryption = '';
1120 # Send EHLO again to receive fresh
1121 # supported commands
1122 $smtp->hello($smtp_domain);
1123 } else {
1124 die "Server does not support STARTTLS! ".$smtp->message;
1125 }
1126 }
1127 }
1128 if (!$smtp) {
1130 die "Unable to initialize SMTP properly. Check config and use --smtp-debug. ",
1131 "VALUES: server=$smtp_server ",
1132 "encryption=$smtp_encryption ",
1133 "hello=$smtp_domain",
1134 defined $smtp_server_port ? " port=$smtp_server_port" : "";
1135 }
1136 if (defined $smtp_authuser) {
1138 # Workaround AUTH PLAIN/LOGIN interaction defect
1139 # with Authen::SASL::Cyrus
1140 eval {
1141 require Authen::SASL;
1142 Authen::SASL->import(qw(Perl));
1143 };
1144 if (!defined $smtp_authpass) {
1146 system "stty -echo";
1148 do {
1150 print "Password: ";
1151 $_ = <STDIN>;
1152 print "\n";
1153 } while (!defined $_);
1154 chomp($smtp_authpass = $_);
1156 system "stty echo";
1158 }
1159 $auth ||= $smtp->auth( $smtp_authuser, $smtp_authpass ) or die $smtp->message;
1161 }
1162 $smtp->mail( $raw_from ) or die $smtp->message;
1164 $smtp->to( @recipients ) or die $smtp->message;
1165 $smtp->data or die $smtp->message;
1166 $smtp->datasend("$header\n$message") or die $smtp->message;
1167 $smtp->dataend() or die $smtp->message;
1168 $smtp->code =~ /250|200/ or die "Failed to send $subject\n".$smtp->message;
1169 }
1170 if ($quiet) {
1171 printf (($dry_run ? "Dry-" : "")."Sent %s\n", $subject);
1172 } else {
1173 print (($dry_run ? "Dry-" : "")."OK. Log says:\n");
1174 if ($smtp_server !~ m#^/#) {
1175 print "Server: $smtp_server\n";
1176 print "MAIL FROM:<$raw_from>\n";
1177 foreach my $entry (@recipients) {
1178 print "RCPT TO:<$entry>\n";
1179 }
1180 } else {
1181 print "Sendmail: $smtp_server ".join(' ',@sendmail_parameters)."\n";
1182 }
1183 print $header, "\n";
1184 if ($smtp) {
1185 print "Result: ", $smtp->code, ' ',
1186 ($smtp->message =~ /\n([^\n]+\n)$/s), "\n";
1187 } else {
1188 print "Result: OK\n";
1189 }
1190 }
1191 return 1;
1193}
1194$reply_to = $initial_reply_to;
1196$references = $initial_reply_to || '';
1197$subject = $initial_subject;
1198$message_num = 0;
1199foreach my $t (@files) {
1201 open my $fh, "<", $t or die "can't open file $t";
1202 my $author = undef;
1204 my $author_encoding;
1205 my $has_content_type;
1206 my $body_encoding;
1207 @to = ();
1208 @cc = ();
1209 @xh = ();
1210 my $input_format = undef;
1211 my @header = ();
1212 $message = "";
1213 $message_num++;
1214 # First unfold multiline header fields
1215 while(<$fh>) {
1216 last if /^\s*$/;
1217 if (/^\s+\S/ and @header) {
1218 chomp($header[$#header]);
1219 s/^\s+/ /;
1220 $header[$#header] .= $_;
1221 } else {
1222 push(@header, $_);
1223 }
1224 }
1225 # Now parse the header
1226 foreach(@header) {
1227 if (/^From /) {
1228 $input_format = 'mbox';
1229 next;
1230 }
1231 chomp;
1232 if (!defined $input_format && /^[-A-Za-z]+:\s/) {
1233 $input_format = 'mbox';
1234 }
1235 if (defined $input_format && $input_format eq 'mbox') {
1237 if (/^Subject:\s+(.*)$/) {
1238 $subject = $1;
1239 }
1240 elsif (/^From:\s+(.*)$/) {
1241 ($author, $author_encoding) = unquote_rfc2047($1);
1242 next if $suppress_cc{'author'};
1243 next if $suppress_cc{'self'} and $author eq $sender;
1244 printf("(mbox) Adding cc: %s from line '%s'\n",
1245 $1, $_) unless $quiet;
1246 push @cc, $1;
1247 }
1248 elsif (/^To:\s+(.*)$/) {
1249 foreach my $addr (parse_address_line($1)) {
1250 printf("(mbox) Adding to: %s from line '%s'\n",
1251 $addr, $_) unless $quiet;
1252 push @to, sanitize_address($addr);
1253 }
1254 }
1255 elsif (/^Cc:\s+(.*)$/) {
1256 foreach my $addr (parse_address_line($1)) {
1257 if (unquote_rfc2047($addr) eq $sender) {
1258 next if ($suppress_cc{'self'});
1259 } else {
1260 next if ($suppress_cc{'cc'});
1261 }
1262 printf("(mbox) Adding cc: %s from line '%s'\n",
1263 $addr, $_) unless $quiet;
1264 push @cc, $addr;
1265 }
1266 }
1267 elsif (/^Content-type:/i) {
1268 $has_content_type = 1;
1269 if (/charset="?([^ "]+)/) {
1270 $body_encoding = $1;
1271 }
1272 push @xh, $_;
1273 }
1274 elsif (/^Message-Id: (.*)/i) {
1275 $message_id = $1;
1276 }
1277 elsif (!/^Date:\s/ && /^[-A-Za-z]+:\s+\S/) {
1278 push @xh, $_;
1279 }
1280 } else {
1282 # In the traditional
1283 # "send lots of email" format,
1284 # line 1 = cc
1285 # line 2 = subject
1286 # So let's support that, too.
1287 $input_format = 'lots';
1288 if (@cc == 0 && !$suppress_cc{'cc'}) {
1289 printf("(non-mbox) Adding cc: %s from line '%s'\n",
1290 $_, $_) unless $quiet;
1291 push @cc, $_;
1292 } elsif (!defined $subject) {
1293 $subject = $_;
1294 }
1295 }
1296 }
1297 # Now parse the message body
1298 while(<$fh>) {
1299 $message .= $_;
1300 if (/^(Signed-off-by|Cc): (.*)$/i) {
1301 chomp;
1302 my ($what, $c) = ($1, $2);
1303 chomp $c;
1304 if ($c eq $sender) {
1305 next if ($suppress_cc{'self'});
1306 } else {
1307 next if $suppress_cc{'sob'} and $what =~ /Signed-off-by/i;
1308 next if $suppress_cc{'bodycc'} and $what =~ /Cc/i;
1309 }
1310 push @cc, $c;
1311 printf("(body) Adding cc: %s from line '%s'\n",
1312 $c, $_) unless $quiet;
1313 }
1314 }
1315 close $fh;
1316 push @to, recipients_cmd("to-cmd", "to", $to_cmd, $t)
1318 if defined $to_cmd;
1319 push @cc, recipients_cmd("cc-cmd", "cc", $cc_cmd, $t)
1320 if defined $cc_cmd && !$suppress_cc{'cccmd'};
1321 if ($broken_encoding{$t} && !$has_content_type) {
1323 $has_content_type = 1;
1324 push @xh, "MIME-Version: 1.0",
1325 "Content-Type: text/plain; charset=$auto_8bit_encoding",
1326 "Content-Transfer-Encoding: 8bit";
1327 $body_encoding = $auto_8bit_encoding;
1328 }
1329 if ($broken_encoding{$t} && !is_rfc2047_quoted($subject) &&
1331 ($subject =~ /[^[:ascii:]]/)) {
1332 $subject = quote_rfc2047($subject, $auto_8bit_encoding);
1333 }
1334 if (defined $author and $author ne $sender) {
1336 $message = "From: $author\n\n$message";
1337 if (defined $author_encoding) {
1338 if ($has_content_type) {
1339 if ($body_encoding eq $author_encoding) {
1340 # ok, we already have the right encoding
1341 }
1342 else {
1343 # uh oh, we should re-encode
1344 }
1345 }
1346 else {
1347 $has_content_type = 1;
1348 push @xh,
1349 'MIME-Version: 1.0',
1350 "Content-Type: text/plain; charset=$author_encoding",
1351 'Content-Transfer-Encoding: 8bit';
1352 }
1353 }
1354 }
1355 $needs_confirm = (
1357 $confirm eq "always" or
1358 ($confirm =~ /^(?:auto|cc)$/ && @cc) or
1359 ($confirm =~ /^(?:auto|compose)$/ && $compose && $message_num == 1));
1360 $needs_confirm = "inform" if ($needs_confirm && $confirm_unconfigured && @cc);
1361 @to = (@initial_to, @to);
1363 @cc = (@initial_cc, @cc);
1364 my $message_was_sent = send_message();
1366 # set up for the next message
1368 if ($thread && $message_was_sent &&
1369 (chain_reply_to() || !defined $reply_to || length($reply_to) == 0 ||
1370 $message_num == 1)) {
1371 $reply_to = $message_id;
1372 if (length $references > 0) {
1373 $references .= "\n $message_id";
1374 } else {
1375 $references = "$message_id";
1376 }
1377 }
1378 $message_id = undef;
1379}
1380# Execute a command (e.g. $to_cmd) to get a list of email addresses
1382# and return a results array
1383sub recipients_cmd {
1384 my ($prefix, $what, $cmd, $file) = @_;
1385 my $sanitized_sender = sanitize_address($sender);
1387 my @addresses = ();
1388 open my $fh, "$cmd \Q$file\E |"
1389 or die "($prefix) Could not execute '$cmd'";
1390 while (my $address = <$fh>) {
1391 $address =~ s/^\s*//g;
1392 $address =~ s/\s*$//g;
1393 $address = sanitize_address($address);
1394 next if ($address eq $sanitized_sender and $suppress_from);
1395 push @addresses, $address;
1396 printf("($prefix) Adding %s: %s from: '%s'\n",
1397 $what, $address, $cmd) unless $quiet;
1398 }
1399 close $fh
1400 or die "($prefix) failed to close pipe to '$cmd'";
1401 return @addresses;
1402}
1403cleanup_compose_files();
1405sub cleanup_compose_files {
1407 unlink($compose_filename, $compose_filename . ".final") if $compose;
1408}
1409$smtp->quit if $smtp;
1411sub unique_email_list {
1413 my %seen;
1414 my @emails;
1415 foreach my $entry (@_) {
1417 if (my $clean = extract_valid_address($entry)) {
1418 $seen{$clean} ||= 0;
1419 next if $seen{$clean}++;
1420 push @emails, $entry;
1421 } else {
1422 print STDERR "W: unable to extract a valid address",
1423 " from: $entry\n";
1424 }
1425 }
1426 return @emails;
1427}
1428sub validate_patch {
1430 my $fn = shift;
1431 open(my $fh, '<', $fn)
1432 or die "unable to open $fn: $!\n";
1433 while (my $line = <$fh>) {
1434 if (length($line) > 998) {
1435 return "$.: patch contains a line longer than 998 characters";
1436 }
1437 }
1438 return undef;
1439}
1440sub file_has_nonascii {
1442 my $fn = shift;
1443 open(my $fh, '<', $fn)
1444 or die "unable to open $fn: $!\n";
1445 while (my $line = <$fh>) {
1446 return 1 if $line =~ /[^[:ascii:]]/;
1447 }
1448 return 0;
1449}
1450sub body_or_subject_has_nonascii {
1452 my $fn = shift;
1453 open(my $fh, '<', $fn)
1454 or die "unable to open $fn: $!\n";
1455 while (my $line = <$fh>) {
1456 last if $line =~ /^$/;
1457 return 1 if $line =~ /^Subject.*[^[:ascii:]]/;
1458 }
1459 while (my $line = <$fh>) {
1460 return 1 if $line =~ /[^[:ascii:]]/;
1461 }
1462 return 0;
1463}