1#!/usr/bin/perl -w
2use strict;
4use Git;
5binmode(STDOUT, ":raw");
7my $repo = Git->repository();
9my $menu_use_color = $repo->get_colorbool('color.interactive');
11my ($prompt_color, $header_color, $help_color) =
12 $menu_use_color ? (
13 $repo->get_color('color.interactive.prompt', 'bold blue'),
14 $repo->get_color('color.interactive.header', 'bold'),
15 $repo->get_color('color.interactive.help', 'red bold'),
16 ) : ();
17my $error_color = ();
18if ($menu_use_color) {
19 my $help_color_spec = ($repo->config('color.interactive.help') or
20 'red bold');
21 $error_color = $repo->get_color('color.interactive.error',
22 $help_color_spec);
23}
24my $diff_use_color = $repo->get_colorbool('color.diff');
26my ($fraginfo_color) =
27 $diff_use_color ? (
28 $repo->get_color('color.diff.frag', 'cyan'),
29 ) : ();
30my ($diff_plain_color) =
31 $diff_use_color ? (
32 $repo->get_color('color.diff.plain', ''),
33 ) : ();
34my ($diff_old_color) =
35 $diff_use_color ? (
36 $repo->get_color('color.diff.old', 'red'),
37 ) : ();
38my ($diff_new_color) =
39 $diff_use_color ? (
40 $repo->get_color('color.diff.new', 'green'),
41 ) : ();
42my $normal_color = $repo->get_color("", "reset");
44my $use_readkey = 0;
46sub ReadMode;
47sub ReadKey;
48if ($repo->config_bool("interactive.singlekey")) {
49 eval {
50 require Term::ReadKey;
51 Term::ReadKey->import;
52 $use_readkey = 1;
53 };
54}
55sub colored {
57 my $color = shift;
58 my $string = join("", @_);
59 if (defined $color) {
61 # Put a color code at the beginning of each line, a reset at the end
62 # color after newlines that are not at the end of the string
63 $string =~ s/(\n+)(.)/$1$color$2/g;
64 # reset before newlines
65 $string =~ s/(\n+)/$normal_color$1/g;
66 # codes at beginning and end (if necessary):
67 $string =~ s/^/$color/;
68 $string =~ s/$/$normal_color/ unless $string =~ /\n$/;
69 }
70 return $string;
71}
72# command line options
74my $patch_mode;
75my $patch_mode_revision;
76sub apply_patch;
78sub apply_patch_for_checkout_commit;
79sub apply_patch_for_stash;
80my %patch_modes = (
82 'stage' => {
83 DIFF => 'diff-files -p',
84 APPLY => sub { apply_patch 'apply --cached', @_; },
85 APPLY_CHECK => 'apply --cached',
86 VERB => 'Stage',
87 TARGET => '',
88 PARTICIPLE => 'staging',
89 FILTER => 'file-only',
90 },
91 'stash' => {
92 DIFF => 'diff-index -p HEAD',
93 APPLY => sub { apply_patch 'apply --cached', @_; },
94 APPLY_CHECK => 'apply --cached',
95 VERB => 'Stash',
96 TARGET => '',
97 PARTICIPLE => 'stashing',
98 FILTER => undef,
99 },
100 'reset_head' => {
101 DIFF => 'diff-index -p --cached',
102 APPLY => sub { apply_patch 'apply -R --cached', @_; },
103 APPLY_CHECK => 'apply -R --cached',
104 VERB => 'Unstage',
105 TARGET => '',
106 PARTICIPLE => 'unstaging',
107 FILTER => 'index-only',
108 },
109 'reset_nothead' => {
110 DIFF => 'diff-index -R -p --cached',
111 APPLY => sub { apply_patch 'apply --cached', @_; },
112 APPLY_CHECK => 'apply --cached',
113 VERB => 'Apply',
114 TARGET => ' to index',
115 PARTICIPLE => 'applying',
116 FILTER => 'index-only',
117 },
118 'checkout_index' => {
119 DIFF => 'diff-files -p',
120 APPLY => sub { apply_patch 'apply -R', @_; },
121 APPLY_CHECK => 'apply -R',
122 VERB => 'Discard',
123 TARGET => ' from worktree',
124 PARTICIPLE => 'discarding',
125 FILTER => 'file-only',
126 },
127 'checkout_head' => {
128 DIFF => 'diff-index -p',
129 APPLY => sub { apply_patch_for_checkout_commit '-R', @_ },
130 APPLY_CHECK => 'apply -R',
131 VERB => 'Discard',
132 TARGET => ' from index and worktree',
133 PARTICIPLE => 'discarding',
134 FILTER => undef,
135 },
136 'checkout_nothead' => {
137 DIFF => 'diff-index -R -p',
138 APPLY => sub { apply_patch_for_checkout_commit '', @_ },
139 APPLY_CHECK => 'apply',
140 VERB => 'Apply',
141 TARGET => ' to index and worktree',
142 PARTICIPLE => 'applying',
143 FILTER => undef,
144 },
145);
146my %patch_mode_flavour = %{$patch_modes{stage}};
148sub run_cmd_pipe {
150 if ($^O eq 'MSWin32' || $^O eq 'msys') {
151 my @invalid = grep {m/[":*]/} @_;
152 die "$^O does not support: @invalid\n" if @invalid;
153 my @args = map { m/ /o ? "\"$_\"": $_ } @_;
154 return qx{@args};
155 } else {
156 my $fh = undef;
157 open($fh, '-|', @_) or die;
158 return <$fh>;
159 }
160}
161my ($GIT_DIR) = run_cmd_pipe(qw(git rev-parse --git-dir));
163if (!defined $GIT_DIR) {
165 exit(1); # rev-parse would have already said "not a git repo"
166}
167chomp($GIT_DIR);
168my %cquote_map = (
170 "b" => chr(8),
171 "t" => chr(9),
172 "n" => chr(10),
173 "v" => chr(11),
174 "f" => chr(12),
175 "r" => chr(13),
176 "\\" => "\\",
177 "\042" => "\042",
178);
179sub unquote_path {
181 local ($_) = @_;
182 my ($retval, $remainder);
183 if (!/^\042(.*)\042$/) {
184 return $_;
185 }
186 ($_, $retval) = ($1, "");
187 while (/^([^\\]*)\\(.*)$/) {
188 $remainder = $2;
189 $retval .= $1;
190 for ($remainder) {
191 if (/^([0-3][0-7][0-7])(.*)$/) {
192 $retval .= chr(oct($1));
193 $_ = $2;
194 last;
195 }
196 if (/^([\\\042btnvfr])(.*)$/) {
197 $retval .= $cquote_map{$1};
198 $_ = $2;
199 last;
200 }
201 # This is malformed -- just return it as-is for now.
202 return $_[0];
203 }
204 $_ = $remainder;
205 }
206 $retval .= $_;
207 return $retval;
208}
209sub refresh {
211 my $fh;
212 open $fh, 'git update-index --refresh |'
213 or die;
214 while (<$fh>) {
215 ;# ignore 'needs update'
216 }
217 close $fh;
218}
219sub list_untracked {
221 map {
222 chomp $_;
223 unquote_path($_);
224 }
225 run_cmd_pipe(qw(git ls-files --others --exclude-standard --), @ARGV);
226}
227my $status_fmt = '%12s %12s %s';
229my $status_head = sprintf($status_fmt, 'staged', 'unstaged', 'path');
230{
232 my $initial;
233 sub is_initial_commit {
234 $initial = system('git rev-parse HEAD -- >/dev/null 2>&1') != 0
235 unless defined $initial;
236 return $initial;
237 }
238}
239sub get_empty_tree {
241 return '4b825dc642cb6eb9a060e54bf8d69288fbee4904';
242}
243# Returns list of hashes, contents of each of which are:
245# VALUE: pathname
246# BINARY: is a binary path
247# INDEX: is index different from HEAD?
248# FILE: is file different from index?
249# INDEX_ADDDEL: is it add/delete between HEAD and index?
250# FILE_ADDDEL: is it add/delete between index and file?
251sub list_modified {
253 my ($only) = @_;
254 my (%data, @return);
255 my ($add, $del, $adddel, $file);
256 my @tracked = ();
257 if (@ARGV) {
259 @tracked = map {
260 chomp $_;
261 unquote_path($_);
262 } run_cmd_pipe(qw(git ls-files --), @ARGV);
263 return if (!@tracked);
264 }
265 my $reference;
267 if (defined $patch_mode_revision and $patch_mode_revision ne 'HEAD') {
268 $reference = $patch_mode_revision;
269 } elsif (is_initial_commit()) {
270 $reference = get_empty_tree();
271 } else {
272 $reference = 'HEAD';
273 }
274 for (run_cmd_pipe(qw(git diff-index --cached
275 --numstat --summary), $reference,
276 '--', @tracked)) {
277 if (($add, $del, $file) =
278 /^([-\d]+) ([-\d]+) (.*)/) {
279 my ($change, $bin);
280 $file = unquote_path($file);
281 if ($add eq '-' && $del eq '-') {
282 $change = 'binary';
283 $bin = 1;
284 }
285 else {
286 $change = "+$add/-$del";
287 }
288 $data{$file} = {
289 INDEX => $change,
290 BINARY => $bin,
291 FILE => 'nothing',
292 }
293 }
294 elsif (($adddel, $file) =
295 /^ (create|delete) mode [0-7]+ (.*)$/) {
296 $file = unquote_path($file);
297 $data{$file}{INDEX_ADDDEL} = $adddel;
298 }
299 }
300 for (run_cmd_pipe(qw(git diff-files --numstat --summary --), @tracked)) {
302 if (($add, $del, $file) =
303 /^([-\d]+) ([-\d]+) (.*)/) {
304 $file = unquote_path($file);
305 if (!exists $data{$file}) {
306 $data{$file} = +{
307 INDEX => 'unchanged',
308 BINARY => 0,
309 };
310 }
311 my ($change, $bin);
312 if ($add eq '-' && $del eq '-') {
313 $change = 'binary';
314 $bin = 1;
315 }
316 else {
317 $change = "+$add/-$del";
318 }
319 $data{$file}{FILE} = $change;
320 if ($bin) {
321 $data{$file}{BINARY} = 1;
322 }
323 }
324 elsif (($adddel, $file) =
325 /^ (create|delete) mode [0-7]+ (.*)$/) {
326 $file = unquote_path($file);
327 $data{$file}{FILE_ADDDEL} = $adddel;
328 }
329 }
330 for (sort keys %data) {
332 my $it = $data{$_};
333 if ($only) {
335 if ($only eq 'index-only') {
336 next if ($it->{INDEX} eq 'unchanged');
337 }
338 if ($only eq 'file-only') {
339 next if ($it->{FILE} eq 'nothing');
340 }
341 }
342 push @return, +{
343 VALUE => $_,
344 %$it,
345 };
346 }
347 return @return;
348}
349sub find_unique {
351 my ($string, @stuff) = @_;
352 my $found = undef;
353 for (my $i = 0; $i < @stuff; $i++) {
354 my $it = $stuff[$i];
355 my $hit = undef;
356 if (ref $it) {
357 if ((ref $it) eq 'ARRAY') {
358 $it = $it->[0];
359 }
360 else {
361 $it = $it->{VALUE};
362 }
363 }
364 eval {
365 if ($it =~ /^$string/) {
366 $hit = 1;
367 };
368 };
369 if (defined $hit && defined $found) {
370 return undef;
371 }
372 if ($hit) {
373 $found = $i + 1;
374 }
375 }
376 return $found;
377}
378# inserts string into trie and updates count for each character
380sub update_trie {
381 my ($trie, $string) = @_;
382 foreach (split //, $string) {
383 $trie = $trie->{$_} ||= {COUNT => 0};
384 $trie->{COUNT}++;
385 }
386}
387# returns an array of tuples (prefix, remainder)
389sub find_unique_prefixes {
390 my @stuff = @_;
391 my @return = ();
392 # any single prefix exceeding the soft limit is omitted
394 # if any prefix exceeds the hard limit all are omitted
395 # 0 indicates no limit
396 my $soft_limit = 0;
397 my $hard_limit = 3;
398 # build a trie modelling all possible options
400 my %trie;
401 foreach my $print (@stuff) {
402 if ((ref $print) eq 'ARRAY') {
403 $print = $print->[0];
404 }
405 elsif ((ref $print) eq 'HASH') {
406 $print = $print->{VALUE};
407 }
408 update_trie(\%trie, $print);
409 push @return, $print;
410 }
411 # use the trie to find the unique prefixes
413 for (my $i = 0; $i < @return; $i++) {
414 my $ret = $return[$i];
415 my @letters = split //, $ret;
416 my %search = %trie;
417 my ($prefix, $remainder);
418 my $j;
419 for ($j = 0; $j < @letters; $j++) {
420 my $letter = $letters[$j];
421 if ($search{$letter}{COUNT} == 1) {
422 $prefix = substr $ret, 0, $j + 1;
423 $remainder = substr $ret, $j + 1;
424 last;
425 }
426 else {
427 my $prefix = substr $ret, 0, $j;
428 return ()
429 if ($hard_limit && $j + 1 > $hard_limit);
430 }
431 %search = %{$search{$letter}};
432 }
433 if (ord($letters[0]) > 127 ||
434 ($soft_limit && $j + 1 > $soft_limit)) {
435 $prefix = undef;
436 $remainder = $ret;
437 }
438 $return[$i] = [$prefix, $remainder];
439 }
440 return @return;
441}
442# filters out prefixes which have special meaning to list_and_choose()
444sub is_valid_prefix {
445 my $prefix = shift;
446 return (defined $prefix) &&
447 !($prefix =~ /[\s,]/) && # separators
448 !($prefix =~ /^-/) && # deselection
449 !($prefix =~ /^\d+/) && # selection
450 ($prefix ne '*') && # "all" wildcard
451 ($prefix ne '?'); # prompt help
452}
453# given a prefix/remainder tuple return a string with the prefix highlighted
455# for now use square brackets; later might use ANSI colors (underline, bold)
456sub highlight_prefix {
457 my $prefix = shift;
458 my $remainder = shift;
459 if (!defined $prefix) {
461 return $remainder;
462 }
463 if (!is_valid_prefix($prefix)) {
465 return "$prefix$remainder";
466 }
467 if (!$menu_use_color) {
469 return "[$prefix]$remainder";
470 }
471 return "$prompt_color$prefix$normal_color$remainder";
473}
474sub error_msg {
476 print STDERR colored $error_color, @_;
477}
478sub list_and_choose {
480 my ($opts, @stuff) = @_;
481 my (@chosen, @return);
482 my $i;
483 my @prefixes = find_unique_prefixes(@stuff) unless $opts->{LIST_ONLY};
484 TOPLOOP:
486 while (1) {
487 my $last_lf = 0;
488 if ($opts->{HEADER}) {
490 if (!$opts->{LIST_FLAT}) {
491 print " ";
492 }
493 print colored $header_color, "$opts->{HEADER}\n";
494 }
495 for ($i = 0; $i < @stuff; $i++) {
496 my $chosen = $chosen[$i] ? '*' : ' ';
497 my $print = $stuff[$i];
498 my $ref = ref $print;
499 my $highlighted = highlight_prefix(@{$prefixes[$i]})
500 if @prefixes;
501 if ($ref eq 'ARRAY') {
502 $print = $highlighted || $print->[0];
503 }
504 elsif ($ref eq 'HASH') {
505 my $value = $highlighted || $print->{VALUE};
506 $print = sprintf($status_fmt,
507 $print->{INDEX},
508 $print->{FILE},
509 $value);
510 }
511 else {
512 $print = $highlighted || $print;
513 }
514 printf("%s%2d: %s", $chosen, $i+1, $print);
515 if (($opts->{LIST_FLAT}) &&
516 (($i + 1) % ($opts->{LIST_FLAT}))) {
517 print "\t";
518 $last_lf = 0;
519 }
520 else {
521 print "\n";
522 $last_lf = 1;
523 }
524 }
525 if (!$last_lf) {
526 print "\n";
527 }
528 return if ($opts->{LIST_ONLY});
530 print colored $prompt_color, $opts->{PROMPT};
532 if ($opts->{SINGLETON}) {
533 print "> ";
534 }
535 else {
536 print ">> ";
537 }
538 my $line = <STDIN>;
539 if (!$line) {
540 print "\n";
541 $opts->{ON_EOF}->() if $opts->{ON_EOF};
542 last;
543 }
544 chomp $line;
545 last if $line eq '';
546 if ($line eq '?') {
547 $opts->{SINGLETON} ?
548 singleton_prompt_help_cmd() :
549 prompt_help_cmd();
550 next TOPLOOP;
551 }
552 for my $choice (split(/[\s,]+/, $line)) {
553 my $choose = 1;
554 my ($bottom, $top);
555 # Input that begins with '-'; unchoose
557 if ($choice =~ s/^-//) {
558 $choose = 0;
559 }
560 # A range can be specified like 5-7 or 5-.
561 if ($choice =~ /^(\d+)-(\d*)$/) {
562 ($bottom, $top) = ($1, length($2) ? $2 : 1 + @stuff);
563 }
564 elsif ($choice =~ /^\d+$/) {
565 $bottom = $top = $choice;
566 }
567 elsif ($choice eq '*') {
568 $bottom = 1;
569 $top = 1 + @stuff;
570 }
571 else {
572 $bottom = $top = find_unique($choice, @stuff);
573 if (!defined $bottom) {
574 error_msg "Huh ($choice)?\n";
575 next TOPLOOP;
576 }
577 }
578 if ($opts->{SINGLETON} && $bottom != $top) {
579 error_msg "Huh ($choice)?\n";
580 next TOPLOOP;
581 }
582 for ($i = $bottom-1; $i <= $top-1; $i++) {
583 next if (@stuff <= $i || $i < 0);
584 $chosen[$i] = $choose;
585 }
586 }
587 last if ($opts->{IMMEDIATE} || $line eq '*');
588 }
589 for ($i = 0; $i < @stuff; $i++) {
590 if ($chosen[$i]) {
591 push @return, $stuff[$i];
592 }
593 }
594 return @return;
595}
596sub singleton_prompt_help_cmd {
598 print colored $help_color, <<\EOF ;
599Prompt help:
6001 - select a numbered item
601foo - select item based on unique prefix
602 - (empty) select nothing
603EOF
604}
605sub prompt_help_cmd {
607 print colored $help_color, <<\EOF ;
608Prompt help:
6091 - select a single item
6103-5 - select a range of items
6112-3,6-9 - select multiple ranges
612foo - select item based on unique prefix
613-... - unselect specified items
614* - choose all items
615 - (empty) finish selecting
616EOF
617}
618sub status_cmd {
620 list_and_choose({ LIST_ONLY => 1, HEADER => $status_head },
621 list_modified());
622 print "\n";
623}
624sub say_n_paths {
626 my $did = shift @_;
627 my $cnt = scalar @_;
628 print "$did ";
629 if (1 < $cnt) {
630 print "$cnt paths\n";
631 }
632 else {
633 print "one path\n";
634 }
635}
636sub update_cmd {
638 my @mods = list_modified('file-only');
639 return if (!@mods);
640 my @update = list_and_choose({ PROMPT => 'Update',
642 HEADER => $status_head, },
643 @mods);
644 if (@update) {
645 system(qw(git update-index --add --remove --),
646 map { $_->{VALUE} } @update);
647 say_n_paths('updated', @update);
648 }
649 print "\n";
650}
651sub revert_cmd {
653 my @update = list_and_choose({ PROMPT => 'Revert',
654 HEADER => $status_head, },
655 list_modified());
656 if (@update) {
657 if (is_initial_commit()) {
658 system(qw(git rm --cached),
659 map { $_->{VALUE} } @update);
660 }
661 else {
662 my @lines = run_cmd_pipe(qw(git ls-tree HEAD --),
663 map { $_->{VALUE} } @update);
664 my $fh;
665 open $fh, '| git update-index --index-info'
666 or die;
667 for (@lines) {
668 print $fh $_;
669 }
670 close($fh);
671 for (@update) {
672 if ($_->{INDEX_ADDDEL} &&
673 $_->{INDEX_ADDDEL} eq 'create') {
674 system(qw(git update-index --force-remove --),
675 $_->{VALUE});
676 print "note: $_->{VALUE} is untracked now.\n";
677 }
678 }
679 }
680 refresh();
681 say_n_paths('reverted', @update);
682 }
683 print "\n";
684}
685sub add_untracked_cmd {
687 my @add = list_and_choose({ PROMPT => 'Add untracked' },
688 list_untracked());
689 if (@add) {
690 system(qw(git update-index --add --), @add);
691 say_n_paths('added', @add);
692 }
693 print "\n";
694}
695sub run_git_apply {
697 my $cmd = shift;
698 my $fh;
699 open $fh, '| git ' . $cmd;
700 print $fh @_;
701 return close $fh;
702}
703sub parse_diff {
705 my ($path) = @_;
706 my @diff_cmd = split(" ", $patch_mode_flavour{DIFF});
707 if (defined $patch_mode_revision) {
708 push @diff_cmd, $patch_mode_revision;
709 }
710 my @diff = run_cmd_pipe("git", @diff_cmd, "--", $path);
711 my @colored = ();
712 if ($diff_use_color) {
713 @colored = run_cmd_pipe("git", @diff_cmd, qw(--color --), $path);
714 }
715 my (@hunk) = { TEXT => [], DISPLAY => [], TYPE => 'header' };
716 for (my $i = 0; $i < @diff; $i++) {
718 if ($diff[$i] =~ /^@@ /) {
719 push @hunk, { TEXT => [], DISPLAY => [],
720 TYPE => 'hunk' };
721 }
722 push @{$hunk[-1]{TEXT}}, $diff[$i];
723 push @{$hunk[-1]{DISPLAY}},
724 ($diff_use_color ? $colored[$i] : $diff[$i]);
725 }
726 return @hunk;
727}
728sub parse_diff_header {
730 my $src = shift;
731 my $head = { TEXT => [], DISPLAY => [], TYPE => 'header' };
733 my $mode = { TEXT => [], DISPLAY => [], TYPE => 'mode' };
734 my $deletion = { TEXT => [], DISPLAY => [], TYPE => 'deletion' };
735 for (my $i = 0; $i < @{$src->{TEXT}}; $i++) {
737 my $dest =
738 $src->{TEXT}->[$i] =~ /^(old|new) mode (\d+)$/ ? $mode :
739 $src->{TEXT}->[$i] =~ /^deleted file/ ? $deletion :
740 $head;
741 push @{$dest->{TEXT}}, $src->{TEXT}->[$i];
742 push @{$dest->{DISPLAY}}, $src->{DISPLAY}->[$i];
743 }
744 return ($head, $mode, $deletion);
745}
746sub hunk_splittable {
748 my ($text) = @_;
749 my @s = split_hunk($text);
751 return (1 < @s);
752}
753sub parse_hunk_header {
755 my ($line) = @_;
756 my ($o_ofs, $o_cnt, $n_ofs, $n_cnt) =
757 $line =~ /^@@ -(\d+)(?:,(\d+))? \+(\d+)(?:,(\d+))? @@/;
758 $o_cnt = 1 unless defined $o_cnt;
759 $n_cnt = 1 unless defined $n_cnt;
760 return ($o_ofs, $o_cnt, $n_ofs, $n_cnt);
761}
762sub split_hunk {
764 my ($text, $display) = @_;
765 my @split = ();
766 if (!defined $display) {
767 $display = $text;
768 }
769 # If there are context lines in the middle of a hunk,
770 # it can be split, but we would need to take care of
771 # overlaps later.
772 my ($o_ofs, undef, $n_ofs) = parse_hunk_header($text->[0]);
774 my $hunk_start = 1;
775 OUTER:
777 while (1) {
778 my $next_hunk_start = undef;
779 my $i = $hunk_start - 1;
780 my $this = +{
781 TEXT => [],
782 DISPLAY => [],
783 TYPE => 'hunk',
784 OLD => $o_ofs,
785 NEW => $n_ofs,
786 OCNT => 0,
787 NCNT => 0,
788 ADDDEL => 0,
789 POSTCTX => 0,
790 USE => undef,
791 };
792 while (++$i < @$text) {
794 my $line = $text->[$i];
795 my $display = $display->[$i];
796 if ($line =~ /^ /) {
797 if ($this->{ADDDEL} &&
798 !defined $next_hunk_start) {
799 # We have seen leading context and
800 # adds/dels and then here is another
801 # context, which is trailing for this
802 # split hunk and leading for the next
803 # one.
804 $next_hunk_start = $i;
805 }
806 push @{$this->{TEXT}}, $line;
807 push @{$this->{DISPLAY}}, $display;
808 $this->{OCNT}++;
809 $this->{NCNT}++;
810 if (defined $next_hunk_start) {
811 $this->{POSTCTX}++;
812 }
813 next;
814 }
815 # add/del
817 if (defined $next_hunk_start) {
818 # We are done with the current hunk and
819 # this is the first real change for the
820 # next split one.
821 $hunk_start = $next_hunk_start;
822 $o_ofs = $this->{OLD} + $this->{OCNT};
823 $n_ofs = $this->{NEW} + $this->{NCNT};
824 $o_ofs -= $this->{POSTCTX};
825 $n_ofs -= $this->{POSTCTX};
826 push @split, $this;
827 redo OUTER;
828 }
829 push @{$this->{TEXT}}, $line;
830 push @{$this->{DISPLAY}}, $display;
831 $this->{ADDDEL}++;
832 if ($line =~ /^-/) {
833 $this->{OCNT}++;
834 }
835 else {
836 $this->{NCNT}++;
837 }
838 }
839 push @split, $this;
841 last;
842 }
843 for my $hunk (@split) {
845 $o_ofs = $hunk->{OLD};
846 $n_ofs = $hunk->{NEW};
847 my $o_cnt = $hunk->{OCNT};
848 my $n_cnt = $hunk->{NCNT};
849 my $head = ("@@ -$o_ofs" .
851 (($o_cnt != 1) ? ",$o_cnt" : '') .
852 " +$n_ofs" .
853 (($n_cnt != 1) ? ",$n_cnt" : '') .
854 " @@\n");
855 my $display_head = $head;
856 unshift @{$hunk->{TEXT}}, $head;
857 if ($diff_use_color) {
858 $display_head = colored($fraginfo_color, $head);
859 }
860 unshift @{$hunk->{DISPLAY}}, $display_head;
861 }
862 return @split;
863}
864sub find_last_o_ctx {
866 my ($it) = @_;
867 my $text = $it->{TEXT};
868 my ($o_ofs, $o_cnt) = parse_hunk_header($text->[0]);
869 my $i = @{$text};
870 my $last_o_ctx = $o_ofs + $o_cnt;
871 while (0 < --$i) {
872 my $line = $text->[$i];
873 if ($line =~ /^ /) {
874 $last_o_ctx--;
875 next;
876 }
877 last;
878 }
879 return $last_o_ctx;
880}
881sub merge_hunk {
883 my ($prev, $this) = @_;
884 my ($o0_ofs, $o0_cnt, $n0_ofs, $n0_cnt) =
885 parse_hunk_header($prev->{TEXT}[0]);
886 my ($o1_ofs, $o1_cnt, $n1_ofs, $n1_cnt) =
887 parse_hunk_header($this->{TEXT}[0]);
888 my (@line, $i, $ofs, $o_cnt, $n_cnt);
890 $ofs = $o0_ofs;
891 $o_cnt = $n_cnt = 0;
892 for ($i = 1; $i < @{$prev->{TEXT}}; $i++) {
893 my $line = $prev->{TEXT}[$i];
894 if ($line =~ /^\+/) {
895 $n_cnt++;
896 push @line, $line;
897 next;
898 }
899 last if ($o1_ofs <= $ofs);
901 $o_cnt++;
903 $ofs++;
904 if ($line =~ /^ /) {
905 $n_cnt++;
906 }
907 push @line, $line;
908 }
909 for ($i = 1; $i < @{$this->{TEXT}}; $i++) {
911 my $line = $this->{TEXT}[$i];
912 if ($line =~ /^\+/) {
913 $n_cnt++;
914 push @line, $line;
915 next;
916 }
917 $ofs++;
918 $o_cnt++;
919 if ($line =~ /^ /) {
920 $n_cnt++;
921 }
922 push @line, $line;
923 }
924 my $head = ("@@ -$o0_ofs" .
925 (($o_cnt != 1) ? ",$o_cnt" : '') .
926 " +$n0_ofs" .
927 (($n_cnt != 1) ? ",$n_cnt" : '') .
928 " @@\n");
929 @{$prev->{TEXT}} = ($head, @line);
930}
931sub coalesce_overlapping_hunks {
933 my (@in) = @_;
934 my @out = ();
935 my ($last_o_ctx, $last_was_dirty);
937 for (grep { $_->{USE} } @in) {
939 if ($_->{TYPE} ne 'hunk') {
940 push @out, $_;
941 next;
942 }
943 my $text = $_->{TEXT};
944 my ($o_ofs) = parse_hunk_header($text->[0]);
945 if (defined $last_o_ctx &&
946 $o_ofs <= $last_o_ctx &&
947 !$_->{DIRTY} &&
948 !$last_was_dirty) {
949 merge_hunk($out[-1], $_);
950 }
951 else {
952 push @out, $_;
953 }
954 $last_o_ctx = find_last_o_ctx($out[-1]);
955 $last_was_dirty = $_->{DIRTY};
956 }
957 return @out;
958}
959sub color_diff {
961 return map {
962 colored((/^@/ ? $fraginfo_color :
963 /^\+/ ? $diff_new_color :
964 /^-/ ? $diff_old_color :
965 $diff_plain_color),
966 $_);
967 } @_;
968}
969sub edit_hunk_manually {
971 my ($oldtext) = @_;
972 my $hunkfile = $repo->repo_path . "/addp-hunk-edit.diff";
974 my $fh;
975 open $fh, '>', $hunkfile
976 or die "failed to open hunk edit file for writing: " . $!;
977 print $fh "# Manual hunk edit mode -- see bottom for a quick guide\n";
978 print $fh @$oldtext;
979 my $participle = $patch_mode_flavour{PARTICIPLE};
980 print $fh <<EOF;
981# ---
982# To remove '-' lines, make them ' ' lines (context).
983# To remove '+' lines, delete them.
984# Lines starting with # will be removed.
985#
986# If the patch applies cleanly, the edited hunk will immediately be
987# marked for $participle. If it does not apply cleanly, you will be given
988# an opportunity to edit again. If all lines of the hunk are removed,
989# then the edit is aborted and the hunk is left unchanged.
990EOF
991 close $fh;
992 chomp(my $editor = run_cmd_pipe(qw(git var GIT_EDITOR)));
994 system('sh', '-c', $editor.' "$@"', $editor, $hunkfile);
995 if ($? != 0) {
997 return undef;
998 }
999 open $fh, '<', $hunkfile
1001 or die "failed to open hunk edit file for reading: " . $!;
1002 my @newtext = grep { !/^#/ } <$fh>;
1003 close $fh;
1004 unlink $hunkfile;
1005 # Abort if nothing remains
1007 if (!grep { /\S/ } @newtext) {
1008 return undef;
1009 }
1010 # Reinsert the first hunk header if the user accidentally deleted it
1012 if ($newtext[0] !~ /^@/) {
1013 unshift @newtext, $oldtext->[0];
1014 }
1015 return \@newtext;
1016}
1017sub diff_applies {
1019 my $fh;
1020 return run_git_apply($patch_mode_flavour{APPLY_CHECK} . ' --recount --check',
1021 map { @{$_->{TEXT}} } @_);
1022}
1023sub _restore_terminal_and_die {
1025 ReadMode 'restore';
1026 print "\n";
1027 exit 1;
1028}
1029sub prompt_single_character {
1031 if ($use_readkey) {
1032 local $SIG{TERM} = \&_restore_terminal_and_die;
1033 local $SIG{INT} = \&_restore_terminal_and_die;
1034 ReadMode 'cbreak';
1035 my $key = ReadKey 0;
1036 ReadMode 'restore';
1037 print "$key" if defined $key;
1038 print "\n";
1039 return $key;
1040 } else {
1041 return <STDIN>;
1042 }
1043}
1044sub prompt_yesno {
1046 my ($prompt) = @_;
1047 while (1) {
1048 print colored $prompt_color, $prompt;
1049 my $line = prompt_single_character;
1050 return 0 if $line =~ /^n/i;
1051 return 1 if $line =~ /^y/i;
1052 }
1053}
1054sub edit_hunk_loop {
1056 my ($head, $hunk, $ix) = @_;
1057 my $text = $hunk->[$ix]->{TEXT};
1058 while (1) {
1060 $text = edit_hunk_manually($text);
1061 if (!defined $text) {
1062 return undef;
1063 }
1064 my $newhunk = {
1065 TEXT => $text,
1066 TYPE => $hunk->[$ix]->{TYPE},
1067 USE => 1,
1068 DIRTY => 1,
1069 };
1070 if (diff_applies($head,
1071 @{$hunk}[0..$ix-1],
1072 $newhunk,
1073 @{$hunk}[$ix+1..$#{$hunk}])) {
1074 $newhunk->{DISPLAY} = [color_diff(@{$text})];
1075 return $newhunk;
1076 }
1077 else {
1078 prompt_yesno(
1079 'Your edited hunk does not apply. Edit again '
1080 . '(saying "no" discards!) [y/n]? '
1081 ) or return undef;
1082 }
1083 }
1084}
1085sub help_patch_cmd {
1087 my $verb = lc $patch_mode_flavour{VERB};
1088 my $target = $patch_mode_flavour{TARGET};
1089 print colored $help_color, <<EOF ;
1090y - $verb this hunk$target
1091n - do not $verb this hunk$target
1092q - quit, do not $verb this hunk nor any of the remaining ones
1093a - $verb this and all the remaining hunks in the file
1094d - do not $verb this hunk nor any of the remaining hunks in the file
1095g - select a hunk to go to
1096/ - search for a hunk matching the given regex
1097j - leave this hunk undecided, see next undecided hunk
1098J - leave this hunk undecided, see next hunk
1099k - leave this hunk undecided, see previous undecided hunk
1100K - leave this hunk undecided, see previous hunk
1101s - split the current hunk into smaller hunks
1102e - manually edit the current hunk
1103? - print help
1104EOF
1105}
1106sub apply_patch {
1108 my $cmd = shift;
1109 my $ret = run_git_apply $cmd . ' --recount', @_;
1110 if (!$ret) {
1111 print STDERR @_;
1112 }
1113 return $ret;
1114}
1115sub apply_patch_for_checkout_commit {
1117 my $reverse = shift;
1118 my $applies_index = run_git_apply 'apply '.$reverse.' --cached --recount --check', @_;
1119 my $applies_worktree = run_git_apply 'apply '.$reverse.' --recount --check', @_;
1120 if ($applies_worktree && $applies_index) {
1122 run_git_apply 'apply '.$reverse.' --cached --recount', @_;
1123 run_git_apply 'apply '.$reverse.' --recount', @_;
1124 return 1;
1125 } elsif (!$applies_index) {
1126 print colored $error_color, "The selected hunks do not apply to the index!\n";
1127 if (prompt_yesno "Apply them to the worktree anyway? ") {
1128 return run_git_apply 'apply '.$reverse.' --recount', @_;
1129 } else {
1130 print colored $error_color, "Nothing was applied.\n";
1131 return 0;
1132 }
1133 } else {
1134 print STDERR @_;
1135 return 0;
1136 }
1137}
1138sub patch_update_cmd {
1140 my @all_mods = list_modified($patch_mode_flavour{FILTER});
1141 my @mods = grep { !($_->{BINARY}) } @all_mods;
1142 my @them;
1143 if (!@mods) {
1145 if (@all_mods) {
1146 print STDERR "Only binary files changed.\n";
1147 } else {
1148 print STDERR "No changes.\n";
1149 }
1150 return 0;
1151 }
1152 if ($patch_mode) {
1153 @them = @mods;
1154 }
1155 else {
1156 @them = list_and_choose({ PROMPT => 'Patch update',
1157 HEADER => $status_head, },
1158 @mods);
1159 }
1160 for (@them) {
1161 return 0 if patch_update_file($_->{VALUE});
1162 }
1163}
1164# Generate a one line summary of a hunk.
1166sub summarize_hunk {
1167 my $rhunk = shift;
1168 my $summary = $rhunk->{TEXT}[0];
1169 # Keep the line numbers, discard extra context.
1171 $summary =~ s/@@(.*?)@@.*/$1 /s;
1172 $summary .= " " x (20 - length $summary);
1173 # Add some user context.
1175 for my $line (@{$rhunk->{TEXT}}) {
1176 if ($line =~ m/^[+-].*\w/) {
1177 $summary .= $line;
1178 last;
1179 }
1180 }
1181 chomp $summary;
1183 return substr($summary, 0, 80) . "\n";
1184}
1185# Print a one-line summary of each hunk in the array ref in
1188# the first argument, starting wih the index in the 2nd.
1189sub display_hunks {
1190 my ($hunks, $i) = @_;
1191 my $ctr = 0;
1192 $i ||= 0;
1193 for (; $i < @$hunks && $ctr < 20; $i++, $ctr++) {
1194 my $status = " ";
1195 if (defined $hunks->[$i]{USE}) {
1196 $status = $hunks->[$i]{USE} ? "+" : "-";
1197 }
1198 printf "%s%2d: %s",
1199 $status,
1200 $i + 1,
1201 summarize_hunk($hunks->[$i]);
1202 }
1203 return $i;
1204}
1205sub patch_update_file {
1207 my $quit = 0;
1208 my ($ix, $num);
1209 my $path = shift;
1210 my ($head, @hunk) = parse_diff($path);
1211 ($head, my $mode, my $deletion) = parse_diff_header($head);
1212 for (@{$head->{DISPLAY}}) {
1213 print;
1214 }
1215 if (@{$mode->{TEXT}}) {
1217 unshift @hunk, $mode;
1218 }
1219 if (@{$deletion->{TEXT}} && !@hunk) {
1220 @hunk = ($deletion);
1221 }
1222 $num = scalar @hunk;
1224 $ix = 0;
1225 while (1) {
1227 my ($prev, $next, $other, $undecided, $i);
1228 $other = '';
1229 if ($num <= $ix) {
1231 $ix = 0;
1232 }
1233 for ($i = 0; $i < $ix; $i++) {
1234 if (!defined $hunk[$i]{USE}) {
1235 $prev = 1;
1236 $other .= ',k';
1237 last;
1238 }
1239 }
1240 if ($ix) {
1241 $other .= ',K';
1242 }
1243 for ($i = $ix + 1; $i < $num; $i++) {
1244 if (!defined $hunk[$i]{USE}) {
1245 $next = 1;
1246 $other .= ',j';
1247 last;
1248 }
1249 }
1250 if ($ix < $num - 1) {
1251 $other .= ',J';
1252 }
1253 if ($num > 1) {
1254 $other .= ',g';
1255 }
1256 for ($i = 0; $i < $num; $i++) {
1257 if (!defined $hunk[$i]{USE}) {
1258 $undecided = 1;
1259 last;
1260 }
1261 }
1262 last if (!$undecided);
1263 if ($hunk[$ix]{TYPE} eq 'hunk' &&
1265 hunk_splittable($hunk[$ix]{TEXT})) {
1266 $other .= ',s';
1267 }
1268 if ($hunk[$ix]{TYPE} eq 'hunk') {
1269 $other .= ',e';
1270 }
1271 for (@{$hunk[$ix]{DISPLAY}}) {
1272 print;
1273 }
1274 print colored $prompt_color, $patch_mode_flavour{VERB},
1275 ($hunk[$ix]{TYPE} eq 'mode' ? ' mode change' :
1276 $hunk[$ix]{TYPE} eq 'deletion' ? ' deletion' :
1277 ' this hunk'),
1278 $patch_mode_flavour{TARGET},
1279 " [y,n,q,a,d,/$other,?]? ";
1280 my $line = prompt_single_character;
1281 if ($line) {
1282 if ($line =~ /^y/i) {
1283 $hunk[$ix]{USE} = 1;
1284 }
1285 elsif ($line =~ /^n/i) {
1286 $hunk[$ix]{USE} = 0;
1287 }
1288 elsif ($line =~ /^a/i) {
1289 while ($ix < $num) {
1290 if (!defined $hunk[$ix]{USE}) {
1291 $hunk[$ix]{USE} = 1;
1292 }
1293 $ix++;
1294 }
1295 next;
1296 }
1297 elsif ($other =~ /g/ && $line =~ /^g(.*)/) {
1298 my $response = $1;
1299 my $no = $ix > 10 ? $ix - 10 : 0;
1300 while ($response eq '') {
1301 my $extra = "";
1302 $no = display_hunks(\@hunk, $no);
1303 if ($no < $num) {
1304 $extra = " (<ret> to see more)";
1305 }
1306 print "go to which hunk$extra? ";
1307 $response = <STDIN>;
1308 if (!defined $response) {
1309 $response = '';
1310 }
1311 chomp $response;
1312 }
1313 if ($response !~ /^\s*\d+\s*$/) {
1314 error_msg "Invalid number: '$response'\n";
1315 } elsif (0 < $response && $response <= $num) {
1316 $ix = $response - 1;
1317 } else {
1318 error_msg "Sorry, only $num hunks available.\n";
1319 }
1320 next;
1321 }
1322 elsif ($line =~ /^d/i) {
1323 while ($ix < $num) {
1324 if (!defined $hunk[$ix]{USE}) {
1325 $hunk[$ix]{USE} = 0;
1326 }
1327 $ix++;
1328 }
1329 next;
1330 }
1331 elsif ($line =~ /^q/i) {
1332 while ($ix < $num) {
1333 if (!defined $hunk[$ix]{USE}) {
1334 $hunk[$ix]{USE} = 0;
1335 }
1336 $ix++;
1337 }
1338 $quit = 1;
1339 next;
1340 }
1341 elsif ($line =~ m|^/(.*)|) {
1342 my $regex = $1;
1343 if ($1 eq "") {
1344 print colored $prompt_color, "search for regex? ";
1345 $regex = <STDIN>;
1346 if (defined $regex) {
1347 chomp $regex;
1348 }
1349 }
1350 my $search_string;
1351 eval {
1352 $search_string = qr{$regex}m;
1353 };
1354 if ($@) {
1355 my ($err,$exp) = ($@, $1);
1356 $err =~ s/ at .*git-add--interactive line \d+, <STDIN> line \d+.*$//;
1357 error_msg "Malformed search regexp $exp: $err\n";
1358 next;
1359 }
1360 my $iy = $ix;
1361 while (1) {
1362 my $text = join ("", @{$hunk[$iy]{TEXT}});
1363 last if ($text =~ $search_string);
1364 $iy++;
1365 $iy = 0 if ($iy >= $num);
1366 if ($ix == $iy) {
1367 error_msg "No hunk matches the given pattern\n";
1368 last;
1369 }
1370 }
1371 $ix = $iy;
1372 next;
1373 }
1374 elsif ($line =~ /^K/) {
1375 if ($other =~ /K/) {
1376 $ix--;
1377 }
1378 else {
1379 error_msg "No previous hunk\n";
1380 }
1381 next;
1382 }
1383 elsif ($line =~ /^J/) {
1384 if ($other =~ /J/) {
1385 $ix++;
1386 }
1387 else {
1388 error_msg "No next hunk\n";
1389 }
1390 next;
1391 }
1392 elsif ($line =~ /^k/) {
1393 if ($other =~ /k/) {
1394 while (1) {
1395 $ix--;
1396 last if (!$ix ||
1397 !defined $hunk[$ix]{USE});
1398 }
1399 }
1400 else {
1401 error_msg "No previous hunk\n";
1402 }
1403 next;
1404 }
1405 elsif ($line =~ /^j/) {
1406 if ($other !~ /j/) {
1407 error_msg "No next hunk\n";
1408 next;
1409 }
1410 }
1411 elsif ($other =~ /s/ && $line =~ /^s/) {
1412 my @split = split_hunk($hunk[$ix]{TEXT}, $hunk[$ix]{DISPLAY});
1413 if (1 < @split) {
1414 print colored $header_color, "Split into ",
1415 scalar(@split), " hunks.\n";
1416 }
1417 splice (@hunk, $ix, 1, @split);
1418 $num = scalar @hunk;
1419 next;
1420 }
1421 elsif ($other =~ /e/ && $line =~ /^e/) {
1422 my $newhunk = edit_hunk_loop($head, \@hunk, $ix);
1423 if (defined $newhunk) {
1424 splice @hunk, $ix, 1, $newhunk;
1425 }
1426 }
1427 else {
1428 help_patch_cmd($other);
1429 next;
1430 }
1431 # soft increment
1432 while (1) {
1433 $ix++;
1434 last if ($ix >= $num ||
1435 !defined $hunk[$ix]{USE});
1436 }
1437 }
1438 }
1439 @hunk = coalesce_overlapping_hunks(@hunk);
1441 my $n_lofs = 0;
1443 my @result = ();
1444 for (@hunk) {
1445 if ($_->{USE}) {
1446 push @result, @{$_->{TEXT}};
1447 }
1448 }
1449 if (@result) {
1451 my $fh;
1452 my @patch = (@{$head->{TEXT}}, @result);
1453 my $apply_routine = $patch_mode_flavour{APPLY};
1454 &$apply_routine(@patch);
1455 refresh();
1456 }
1457 print "\n";
1459 return $quit;
1460}
1461sub diff_cmd {
1463 my @mods = list_modified('index-only');
1464 @mods = grep { !($_->{BINARY}) } @mods;
1465 return if (!@mods);
1466 my (@them) = list_and_choose({ PROMPT => 'Review diff',
1467 IMMEDIATE => 1,
1468 HEADER => $status_head, },
1469 @mods);
1470 return if (!@them);
1471 my $reference = is_initial_commit() ? get_empty_tree() : 'HEAD';
1472 system(qw(git diff -p --cached), $reference, '--',
1473 map { $_->{VALUE} } @them);
1474}
1475sub quit_cmd {
1477 print "Bye.\n";
1478 exit(0);
1479}
1480sub help_cmd {
1482 print colored $help_color, <<\EOF ;
1483status - show paths with changes
1484update - add working tree state to the staged set of changes
1485revert - revert staged set of changes back to the HEAD version
1486patch - pick hunks and update selectively
1487diff - view diff between HEAD and index
1488add untracked - add contents of untracked files to the staged set of changes
1489EOF
1490}
1491sub process_args {
1493 return unless @ARGV;
1494 my $arg = shift @ARGV;
1495 if ($arg =~ /--patch(?:=(.*))?/) {
1496 if (defined $1) {
1497 if ($1 eq 'reset') {
1498 $patch_mode = 'reset_head';
1499 $patch_mode_revision = 'HEAD';
1500 $arg = shift @ARGV or die "missing --";
1501 if ($arg ne '--') {
1502 $patch_mode_revision = $arg;
1503 $patch_mode = ($arg eq 'HEAD' ?
1504 'reset_head' : 'reset_nothead');
1505 $arg = shift @ARGV or die "missing --";
1506 }
1507 } elsif ($1 eq 'checkout') {
1508 $arg = shift @ARGV or die "missing --";
1509 if ($arg eq '--') {
1510 $patch_mode = 'checkout_index';
1511 } else {
1512 $patch_mode_revision = $arg;
1513 $patch_mode = ($arg eq 'HEAD' ?
1514 'checkout_head' : 'checkout_nothead');
1515 $arg = shift @ARGV or die "missing --";
1516 }
1517 } elsif ($1 eq 'stage' or $1 eq 'stash') {
1518 $patch_mode = $1;
1519 $arg = shift @ARGV or die "missing --";
1520 } else {
1521 die "unknown --patch mode: $1";
1522 }
1523 } else {
1524 $patch_mode = 'stage';
1525 $arg = shift @ARGV or die "missing --";
1526 }
1527 die "invalid argument $arg, expecting --"
1528 unless $arg eq "--";
1529 %patch_mode_flavour = %{$patch_modes{$patch_mode}};
1530 }
1531 elsif ($arg ne "--") {
1532 die "invalid argument $arg, expecting --";
1533 }
1534}
1535sub main_loop {
1537 my @cmd = ([ 'status', \&status_cmd, ],
1538 [ 'update', \&update_cmd, ],
1539 [ 'revert', \&revert_cmd, ],
1540 [ 'add untracked', \&add_untracked_cmd, ],
1541 [ 'patch', \&patch_update_cmd, ],
1542 [ 'diff', \&diff_cmd, ],
1543 [ 'quit', \&quit_cmd, ],
1544 [ 'help', \&help_cmd, ],
1545 );
1546 while (1) {
1547 my ($it) = list_and_choose({ PROMPT => 'What now',
1548 SINGLETON => 1,
1549 LIST_FLAT => 4,
1550 HEADER => '*** Commands ***',
1551 ON_EOF => \&quit_cmd,
1552 IMMEDIATE => 1 }, @cmd);
1553 if ($it) {
1554 eval {
1555 $it->[1]->();
1556 };
1557 if ($@) {
1558 print "$@";
1559 }
1560 }
1561 }
1562}
1563process_args();
1565refresh();
1566if ($patch_mode) {
1567 patch_update_cmd();
1568}
1569else {
1570 status_cmd();
1571 main_loop();
1572}